Quick fixes - OpenStreetMap Wiki

SELECT
  ?id  ?loc
  (osmt:motor_vehicle as ?tag_1)   (false as ?val_1)
WHERE {
  VALUES ?truthy { 'yes' 'true' '1' }
  VALUES ?highway { 'motorway' 'trunk' 'primary' 'secondary' 'tertiary' 'unclassified' 'residential' 'service' 'living_street' }
  ?id osmt:motor_vehicle ?truthy ;
      osmt:highway ?highway ;
      osmm:loc ?loc .
  OPTIONAL { ?id osmt:vehicle ?vehicle }
  OPTIONAL { ?id osmt:access ?access }
  OPTIONAL { ?id osmt:bicycle_road ?bicycle_road }

  FILTER (
    (!BOUND(?vehicle) || ?vehicle != 'no') &&
    (!BOUND(?access) || ?access != 'no') &&
    (!BOUND(?bicycle_road) || ?bicycle_road != 'yes')
  )
}

SELECT
  ?id  ?loc
  (osmt:area as ?tag_1)   (false as ?val_1)
WHERE {
  VALUES ?truthy { 'yes' 'true' '1' }
  VALUES ?tags { osmt:amenity osmt:landuse osmt:leisure }
  ?id osmt:area ?truthy ;
      ?tags ?anything ;
      osmm:isClosed true ;   # closed only applies to ways
      osmm:loc ?loc .
  MINUS { ?id osmt:highway ?highway }
}

SELECT
  ?id  ?loc
  (osmt:area as ?tag_1)   (false as ?val_1)
WHERE {
  VALUES ?truthy { 'yes' 'true' '1' }
  VALUES ?tags { osmt:building osmt:natural osmt:shop }
  ?id osmt:area ?truthy ;
      ?tags ?anything ;
      osmm:isClosed true ;   # closed only applies to ways
      osmm:loc ?loc .
}

SELECT
  ?id  ?loc
  (osmt:area as ?tag_1)   (false as ?val_1)
WHERE {
  VALUES ?truthy { 'yes' 'true' '1' }
  VALUES ?aeroway { 'aerodrome' 'helipad' }
  ?id osmt:area ?truthy ;
      osmt:aeroway ?aeroway ;
      osmm:isClosed true ;   # closed only applies to ways
      osmm:loc ?loc .
}

SELECT
  ?id  ?loc
  (?wptag as ?tag_1)   (IRI(REPLACE(STR(?wp), '/cz.', '/cs.')) as ?val_1)
WHERE {
  VALUES ?wptag {osmt:wikipedia osmt:brand:wikipedia osmt:operator:wikipedia osmt:subject:wikipedia osmt:artist:wikipedia osmt:name:entomology:wikipedia}
  ?id ?wptag ?wp ;
      osmm:loc ?loc .
  FILTER (STRSTARTS(STR(?wp), 'https://cz.wikipedia.org/'))
}

https://josm.openstreetmap.de/browser/josm/trunk/data/validator/wikipedia.mapcss?rev=12493#L89", "taskId":"josm_layer_plus",  "minZoom":13 }
SELECT
  ?id  ?loc
  # keep the very last language prefix in the title
  (?wptag as ?tag_1)   (IRI(REPLACE(STR(?wp), '[a-z][a-z]\\.wikipedia\\.org/wiki/([a-z][a-z]:)*([a-z][a-z]):', '$2.wikipedia.org/wiki/')) as ?val_1)
WHERE {
  VALUES ?wptag {osmt:wikipedia osmt:brand:wikipedia osmt:operator:wikipedia osmt:subject:wikipedia osmt:artist:wikipedia osmt:name:entomology:wikipedia}
  ?id ?wptag ?wp ;
      osmm:loc ?loc .
  FILTER (REGEX(STR(?wp), 'https://([a-z][a-z])\\.wikipedia\\.org/wiki/[a-z][a-z]:'))
}

SELECT
  ?id  ?loc
  (osmt:bridge as ?tag_1)   ('aqueduct' as ?val_1)
WHERE {
  VALUES ?truthy { 'yes' 'true' '1' }
  ?id osmt:bridge ?truthy ;
      osmt:waterway ?waterway ;
      osmm:type 'w' ;
      osmm:loc ?loc .
  FILTER (?waterway != 'weir')
}

SELECT
  ?id  ?loc
  (osmt:addr:postcode as ?tag_1)   (false as ?val_1)
WHERE {
  ?id osmt:highway ?highway ;
      osmt:postal_code ?code ;
      osmt:addr:postcode ?code ;
      osmm:type 'w' ;
      osmm:loc ?loc .
}

SELECT
  ?id  ?loc
  (osmt:addr:postcode as ?tag_1)  (false as ?val_1)
  (osmt:postal_code as ?tag_2)    (?postal_code as ?val_2)

WHERE {
  ?id osmt:addr:postcode ?addr_postcode ;
      osmt:highway ?highway ;
      osmm:type 'w' ;
      osmm:loc ?loc .

  FILTER ( ?highway != 'services' && ?highway != 'rest_area' )
  MINUS {  ?id osmt:postal_code ?postal_code . }
}

SELECT
  ?id  ?loc
  (osmt:maxspeed:forward as ?tag_1)   (false as ?val_1)
  (osmt:maxspeed:backward as ?tag_2)  (false as ?val_2)
  (osmt:maxspeed as ?tag_3)           (?maxspeed as ?val_3)

WHERE {
  ?id osmt:maxspeed:forward ?maxspeed ;
      osmt:maxspeed:backward ?maxspeed ;
      osmm:loc ?loc .

  OPTIONAL { ?id osmt:maxspeed ?opt_maxspeed }
  FILTER( !BOUND(?opt_maxspeed) || ?opt_maxspeed = ?maxspeed )
  
}

SELECT
  ?id  ?loc
  (osmt:female as ?tag_1)   (false as ?val_1)
  (osmt:male as ?tag_2)     (false as ?val_2)
  (osmt:unisex as ?tag_3)   ('yes' as ?val_3)
WHERE {
  VALUES ?truthy { 'yes' 'true' '1' }
  ?id osmt:female ?truthy ;
      osmt:male ?truthy ;
      osmt:shop ?hairdresser ;
      osmm:loc ?loc .

  MINUS { ?id osmt:unisex ?unisex }
}

SELECT
  ?id  ?loc
  (osmt:source:geometry as ?tag_1)   (false as ?val_1)
  (osmt:source:position as ?tag_2)   (?value as ?val_2)
WHERE {
  ?id osmt:source:geometry ?value ;
      osmm:type 'n' ;
      osmm:loc ?loc .
}

SELECT
  ?id  ?loc
  (osmt:wikidata as ?tag_1)   (false as ?val_1)
  (osmt:wikipedia as ?tag_2)  (false as ?val_2)
WHERE {  
  # Get OSM features where tags wikidata = brand:wikidata
  ?id osmt:wikidata ?wd ;
         osmt:brand:wikidata ?wd ;
         osmm:loc ?loc .
  
  OPTIONAL { ?id osmt:wikipedia ?wp }
  OPTIONAL { ?id osmt:brand:wikipedia ?bwp }
  
  # Either wikipedia tag is missing, or it must be the same as brand:wikipedia
  FILTER (!BOUND(?wp) || (BOUND(?bwp) && ?wp = ?bwp))

  # TODO: Handle wikipedia tag:
  # If no brand:wikipedia:  if wikipedia tag matches wikidata tag, move it to brand:wikipedia.
  # If brand:wikipedia exists, ensure that it also matches wikidata, and if so, delete wikipedia tag.
  
  # Get labels for the Wikidata entry, and for all occupations
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,de,fr,it,pl,ru,es,sv,nl" .
    ?wd rdfs:label ?wdLabel .
  }
}

SELECT
  # Generate output fields - id of the object, mark location, and the changeset comment
  ?id  ?loc 

  # Delete existing amenity tag by setting ?val_1 to false
  (osmt:amenity as ?tag_1)   (false as ?val_1)

  # Set leisure tag to the value 'resort'
  (osmt:leisure as ?tag_2)   ('resort' as ?val_2)

  # Set resort tag to the value 'sanatorium'
  (osmt:resort as ?tag_3)    ('sanatorium' as ?val_3)

WHERE {
  # Must have amenity=sanatorium and a location.
  ?id osmt:amenity 'sanatorium' ;
      osmm:loc ?loc .

  # Ignore if leisure tag already exists, and not set to 'resort'
  OPTIONAL { ?id osmt:leisure ?leisure }
  FILTER (!BOUND(?leisure) || ?leisure = 'resort')

  # Ignore if resort tag already exists, and not set to 'sanatorium'
  OPTIONAL { ?id osmt:resort ?resort }
  FILTER (!BOUND(?resort) || ?resort = 'sanatorium')
}

SELECT
  ?id  ?loc
  (osmt:religion as ?tag_1)   ('christian' as ?val_1)
WHERE {
  VALUES ?religion { 'Christian' }
  
  ?id osmt:religion ?religion ;
      osmm:loc ?loc .
}

SELECT
  ?id  ?loc
  (osmt:religion as ?tag_1)       ('christian' as ?val_1)
  (osmt:denomination as ?tag_2)   (?religion as ?val_2)
WHERE {
  VALUES ?religion { 'mormon' 'anglican' }
  
  ?id osmt:religion ?religion ;
      osmm:loc ?loc .

  # Ignore if denomination tag already exists, and not set to the needed value
  OPTIONAL { ?id osmt:denomination ?denomination }
  FILTER (!BOUND(?denomination) || ?denomination = ?religion)
}

SELECT
  # Generate output fields - id of the object, mark location, and the change set comment
  ?id  ?loc
  (osmt:religion as ?tag_1)      ('christian' as ?val_1)
  (osmt:denomination as ?tag_2)  (?denomination as ?val_2)
WHERE {

  BIND ('catholic' as ?denomination)
  VALUES ?religion { 'catholic' 'catolica' }
  VALUES ?religion2 { 'catholic' 'catolica' }

  ?id osmt:religion ?religion ;
      osmm:loc ?loc .

  # Ignore if denomination tag already exists, and not set to the needed value
  OPTIONAL { ?id osmt:denomination ?den }
  FILTER (!BOUND(?den) || ?den = ?religion2)
}

SELECT
  ?id  ?loc
  (osmt:religion as ?tag_1)   ('muslim' as ?val_1)
WHERE {
  VALUES ?religion { 'Islam' 'islam' }
  
  ?id osmt:religion ?religion ;
      osmm:loc ?loc .
}

SELECT
  ?id  ?loc
  (osmt:sport as ?tag_a1)  ('scuba_diving' as ?val_a1)
  (osmt:sport as ?tag_b1)  ('cliff_diving' as ?val_b1)
WHERE {
  ?id osmt:sport 'diving' .
  ?id osmm:loc ?loc .
}

SELECT
  ?id  ?loc
  (osmt:amenity as ?tag_a1)  ('college'    as ?val_a1)
  (osmt:amenity as ?tag_b1)  ('school'     as ?val_b1)
  (osmt:amenity as ?tag_c1)  ('university' as ?val_c1)
  (osmt:amenity as ?tag_d1)  (false        as ?val_d1)
  (osmt:office  as ?tag_d2)  ('tutoring'   as ?val_d2)
WHERE {
  ?id osmt:amenity 'education' .
  ?id osmm:loc ?loc .
}

SELECT
  ?id  ?loc
  (osmt:shop  as ?tag_a1)  ('houseware' as ?val_a1)
  (osmt:shop  as ?tag_b1)  ('heating'   as ?val_b1)
  (osmt:shop  as ?tag_c1)  (false       as ?val_c1)
  (osmt:craft as ?tag_c2)  ('plumber'   as ?val_c2)
WHERE {
  ?id osmt:shop 'furnace' .
  ?id osmm:loc ?loc .
}

SELECT
  ?id  ?loc
  (osmt:amenity as ?tag_a1)  ('childcare'    as ?val_a1)
  (osmt:amenity as ?tag_b1)  ('kindergarten' as ?val_b1)
WHERE {
  VALUES ?amenity { 'creche' 'nursery' }
  ?id osmt:amenity ?amenity .
  ?id osmm:loc ?loc .
}

SELECT
  ?id  ?loc
  (osmt:landuse as ?tag_a1)  ('farmyard' as ?val_a1)
  (osmt:landuse as ?tag_b1)  ('farmland' as ?val_b1)
WHERE {
  ?id osmt:landuse 'farm' .
  ?id osmm:loc ?loc .
}

SELECT
  ?id  ?loc
  (osmt:power as ?tag_a1)  ('substation' as ?val_a1)
  (osmt:power as ?tag_b1)  ('plant'      as ?val_b1)
  (osmt:power as ?tag_c1)  ('generator'  as ?val_c1)
WHERE {
  ?id osmt:power 'station' .
  ?id osmm:loc ?loc .
}

SELECT
  ?id  ?loc
  (osmt:landuse as ?tag_a1)  ('forest' as ?val_a1)
  (osmt:natural as ?tag_b1)  ('wood'   as ?val_b1)
  (osmt:landuse as ?tag_b2)  (false    as ?val_b2)
WHERE {
  ?id osmt:landuse 'wood' .
  ?id osmm:loc ?loc .
}